EXCEL大众情人丨Vlookup函数详解

日常工作中，经常需要对数据进行查询引用。VLOOKUP函数是工作中使用率较高的查询函数之一，熟练使用VLOOKUP函数能够在查询引用数据中运用自如，提高我们的工作效率。

VLOOKUP函数语法：

VLOOKUP(查找值，查找区域，结果所在查找区域的列序号，模糊查找还是精确查找）

01

VLOOKUP单条件查找

案例：如下图,我们需要根据给定的姓名查找出对应的科目

F4公式=VLOOKUP(E4,$A$2:$B$8,2,0)

公式说明：

查找值：指定查找目标“ExcelTip”，所以下一步就要指定从哪个区域中进行查找

查找区域：查找值必须要在查找区域的首列，查找区域要包含返回的结果，ExcelTip在A列的姓名区域，所以选择$A$2:$B$8

列序号：它是返回值在查找区域中的列数，比如我们的返回值是销量，那么$A$2:$B$8区域，科目属于第几列呢？很明显 是第2列，所以写上2

查找方式：模糊or精确查找，如果值为1或TRUE表示模糊查找，如果值为0或FALSE表示精确查找

02

VLOOKUP多条件查找

单个条件查找是工作中经常使用的，但如果需要同时满足多个条件进行查找 怎么办？ 如下案例，我们需要同时满足两个条件，查询出姓名和产品对应的销量

在G2单元格输入数组公式，按Ctrl+Shift+Enter 组合键结束公式

=VLOOKUP(E2&F2,IF({1,0},$A$2:$A$10&$B$2:$B$10,$C$2:$C$10),2,0)

公式说明：

首先我们查找值为E2&F2就是把姓名和产品连接在一起得到 "小螃蟹冰箱"

查找区域使用

IF({1,0},$A$2:$A$10&$B$2:$B$10,$C$2:$C$10) 把姓名列和产品列连接在一起，也就是把姓名和产品组合为一列，然后销量为第2列，返回一个多行两列的内存数组，再用VLOOKUP查询即可

03

VLOOKUP逆向查找

VLOOKUP只能从左向右查找，但如果需要从右向左查找怎么办？

如下案例，需要根据销量查询产品

G2公式：

=VLOOKUP(F2,IF({1,0},$C$2:$C$10,$B$2:$B$10),2,0)

公式说明：

和上面多条件查找案例类似，首先查找销量，使用IF({1,0},$C$2:$C$10,$B$2:$B$10) 返回一个销量在前，产品在后的多行两列内存数组，让它符合VLOOKUP函数的查询值处于查询区域的首列，再用VOOKUP进行查询即可

04

VLOOKUP返回多列数据

如下案例，需要根据查找姓名返回多列数据，那么如何输入一个公式搞定一个区域的数据查找呢？

H2公式：

=VLOOKUP($G2,$A$2:$E$10,MATCH(H$1,$A$1:$E$1,0),0)

公式说明：

公式其他都没什么变化，主要是第三个参数 返回的列序号，因为公式的移动填充，我们不能确定它是返回第几列，所以在这里我们使用MATCH(H$1,$A$1:$E$1,0) 帮我们去查找科目所在查找区域中的列序号，最后返回一个准确的数据。

05

VLOOKUP使用通配符查找

当我们在查找的时候，只根据查找值的一部分数据查找时，可以使用通配符查询，例如下图，需根据名称给定的简称查找出数量

E2公式：

=VLOOKUP("*"&D2&"*",$A$2:$B$8,2,0)

公式说明：

*是通配符，可以代表任意多个字符，这里根据查找名称的简称，因为查找区域跟查找值不符，如果不使用通配符必定会返回错误值，"*"&D2&"*" 表示区域中包含蓝莓的就会被找到

本文来源于ExcelTip，版权归作者所有，感谢作者的辛苦付出，若涉及版权请告知我们，我们会在第一时间处理。我们对文中观点保持中立，仅供参考、交流之目的！

推荐阅读：

置顶功能：点开“财税地盘”公众号，点右上角人像按钮，然后点“置顶公众号”键，就可以将我们置顶了。这样，您就可以第一时间发现我们。

欢迎加入财税地盘微信群及系列QQ群（QQ交流群：44808534），与全国会计同行在线交流！