原来这才是查看盲评结果的正确方式

本文作者：闫续文

文字编辑：朱巧利

技术总编：张计宝

导读

又是一年毕业季，三年研究生生涯转瞬即逝。随着研究生学位论文盲评结果的返回，毕业生们紧绷的神经也终于放松了不少。在盲评结束后，我们通常会收到汇总了不同盲评专家对于学位论文评分与意见的Excel文件。下图是今年我们团队9名毕业生的盲评结果。

在这个Excel文件中，详细地列出了每名毕业生学位论文的题目、3位盲评专家打出的总分、意见与建议。我们发现，虽然在Excel里，单元格中信息的相互关系一目了然，非常直观，但是当文字或其他内容过长时，单元格的长度往往是不够的，一个单元格无法完全显示其中的所有内容，我们需要双击单元格才可以查看全部内容。以“总体评价意见”为例，当我们双击D2单元格时，可以看到该单元格中的所有内容。

此时，虽然D2单元格显示了完整的内容，但是会遮挡住后方和下方很多单元格，而且每次查看单元格内容都要双击也有些麻烦。对于这种情况，我们推荐大家将Excel中的内容导出到Word以方便阅读。当然，如果是在范围很小、工作量不大的情况下，我们可以选择将单元格中的内容一个个复制粘贴到Word中，但如果面对的是大量需要导出内容的单元格，我们最好的选择仍旧是通过编程来实现这一操作，减少手工劳动。

导读导读

Step 1

首先，我们将盲评结果的Excel文件导入Stata中，程序如下：

clear all
cd D:/盲评结果
import excel using 盲评结果.xlsx, clear first

Step 2

其次，我们借助Putdocx命令，将第一名毕业生的论文题目、姓名与3位盲评专家打出的总分输出到Word中，并将这些内容放入同一个表格中，程序如下：

putdocx begin 
putdocx table table1 = (3,6), halign(center) layout(autofitwindow)  //生成3行6列的表格，设置表格居中对齐并根据窗口大小自动调整列宽
putdocx table table1(1,1) = ("论文题目"), bold  //在第1行第1列单元格中插入文字“论文题目”，并加粗显示
putdocx table table1(1,2) = (论文题目[1]), colspan(5)  //在第1行第2列单元格中插入变量“论文题目”的第1个观测值，并将由此向右共5列单元格合并为1个单元格
putdocx table table1(2,1) = ("姓名"), bold
putdocx table table1(2,2) = (姓名[1]), colspan(5)
putdocx table table1(3,1) = ("总分1"), bold
putdocx table table1(3,2) = (总分[1])  
putdocx table table1(3,3) = ("总分2"), bold
putdocx table table1(3,4) = (总分[2])
putdocx table table1(3,5) = ("总分3"), bold
putdocx table table1(3,6) = (总分[3])
putdocx save 盲评结果.docx, replace

输出到Word中的表格如下图所示：

Step 3

接下来，我们将每位盲评专家的意见和建议以段落的形式分别输出到Word中，程序如下：

putdocx begin 
putdocx paragraph, halign(left)
putdocx text ("总体评价意见"), font("黑体",12,black) bold 
putdocx paragraph, halign(both) indent(para,0.74cm)  //设置段落两端对齐，并设置段落首行缩进0.74cm
putdocx text (总体评价意见[1]), font("宋体",11,black)  //将变量“总体评价意见”的第1个观测值输出到该段落中，并设置字体字号颜色
putdocx paragraph, halign(both) indent(para,0.74cm)
putdocx text (总体评价意见[2]), font("宋体",11,black)
putdocx paragraph, halign(both) indent(para,0.74cm)
putdocx text (总体评价意见[3]), font("宋体",11,black) 
putdocx paragraph, halign(left)
putdocx text ("总体评价建议"), font("黑体",12,black) bold 
putdocx paragraph, halign(both) indent(para,0.74cm)
putdocx text (总体评价建议[1]), font("宋体",11,black)
putdocx paragraph, halign(both) indent(para,0.74cm)
putdocx text (总体评价建议[2]), font("宋体",11,black)
putdocx paragraph, halign(both) indent(para,0.74cm)
putdocx text (总体评价建议[3]), font("宋体",11,black)
putdocx save 盲评结果.docx, append

至此，输出到Word中的所有内容如下图所示：

我们发现，当把Excel单元格中的内容导出到Word之后，所有的内容就都变得十分清晰，能够方便后续根据盲评意见对学位论文做出进一步的修改。

对于我们团队中剩下8名毕业生的盲评结果，我们只需要将上述程序加入到循环中即可，完整程序如下：

clear all
cd D:/盲评结果
import excel using 盲评结果.xlsx, clear first 
putdocx begin 
putdocx save 盲评结果.docx, replace
forvalue i = 1(3)25 {
  putdocx begin 
  putdocx table table1 = (3,6), halign(center) layout(autofitwindow) 
  putdocx table table1(1,1) = ("论文题目"), bold
  putdocx table table1(1,2) = (论文题目[`i']), colspan(5)
  putdocx table table1(2,1) = ("姓名"), bold
  putdocx table table1(2,2) = (姓名[`i']), colspan(5)
  putdocx table table1(3,1) = ("总分1"), bold
  putdocx table table1(3,2) = (总分[`i']) 
  putdocx table table1(3,3) = ("总分2"), bold
  putdocx table table1(3,4) = (总分[`i'+1])
  putdocx table table1(3,5) = ("总分3"), bold
  putdocx table table1(3,6) = (总分[`i'+2])
  putdocx paragraph, halign(left)
  putdocx text ("总体评价意见"), font("黑体",12,black) bold 
  putdocx paragraph, halign(both) indent(para,0.74cm)
  putdocx text (总体评价意见[`i']), font("宋体",11,black)
  putdocx paragraph, halign(both) indent(para,0.74cm)
  putdocx text (总体评价意见[`i'+1]), font("宋体",11,black)
  putdocx paragraph, halign(both) indent(para,0.74cm)
  putdocx text (总体评价意见[`i'+2]), font("宋体",11,black) 
  putdocx paragraph, halign(left)
  putdocx text ("总体评价建议"), font("黑体",12,black) bold 
  putdocx paragraph, halign(both) indent(para,0.74cm)
  putdocx text (总体评价建议[`i']), font("宋体",11,black)
  putdocx paragraph, halign(both) indent(para,0.74cm)
  putdocx text (总体评价建议[`i'+1]), font("宋体",11,black)
  putdocx paragraph, halign(both) indent(para,0.74cm)
  putdocx text (总体评价建议[`i'+2]), font("宋体",11,black) 
  putdocx pagebreak
  putdocx save 盲评结果.docx, append
}
shellout 盲评结果.docx

最后，无论是继续学术生涯，还是进入职场工作，愿你们未来的每一程，都有美好风景，都能遇到温暖的人。

对我们的推文累计打赏超过1000元，我们即可给您开具发票，发票类别为“咨询费”。用心做事，不负您的支持！

往期推文推荐

关于我们

微信公众号“Stata and Python数据分析”分享实用的stata、python等软件的数据处理知识，欢迎转载、打赏。我们是由李春涛教授领导下的研究生及本科生组成的大数据处理和分析团队。

此外，欢迎大家踊跃投稿，介绍一些关于stata和python的数据处理和分析技巧。

投稿邮箱：[e-mail]

投稿要求：
1）必须原创，禁止抄袭；
2）必须准确，详细，有例子，有截图；
注意事项：
1）所有投稿都会经过本公众号运营团队成员的审核，审核通过才可录用，一经录用，会在该推文里为作者署名，并有赏金分成。
2）邮件请注明投稿，邮件名称为“投稿+推文名称”。
3）应广大读者要求，现开通有偿问答服务，如果大家遇到有关数据处理、分析等问题，可以在公众号中提出，只需支付少量赏金，我们会在后期的推文里给予解答。